Dynamics AX: SalesTable2LineField

In der Auftragserfassung gibt es im Auftragskopf Felder, die, wenn sie aktualisiert werden, entweder vollautomatisch bzw. nach Rückfrage beim Benutzer in den Auftragszeilen ebenfalls aktualisiert werden. Welche Felder das sind kann in den Debitorenparametern, Register Aktualisierungen über die Schaltfläche Auftragspositionen aktualisieren eingesehen werden. Dort kann auch parametriert werden, wie sich Dynamics AX bei der Aktualisierung dieser Felder verhalten soll.

Um nun ein weiteres Feld in diese Logik mitaufzunehmen bedarf es einiger Schritte. Im folgenden demonstriere ich die notwendigen Änderungen anhand des neuen Feldes DevReceiptDateRequested (abgeleitet vom EDT DevSalesReceiptDateRequested):

• Neues Feld in Tabelle Salestable und Salesline anlegen
• Das neue Feld in der Salestable in die Fieldgroup HeaderToLineUpdate integrieren
• In der Klasse SalesTable2LineField die Methode lineUpdateDescription um das neue Feld erweitern (einfach die Logik eines bestehenden Feldes abschreiben)
• In der Klasse SalesLineType die Methode initFromSalesTable um das neue Feld erweitern (einfach die Logik eines bestehenden Feldes abschreiben)
• In der Klasse AxSalesline eine neue Methode wie folgt erstellen

  protected boolean isDevReceiptDateRequestedSet()
  {
       return this.isFieldSet(fieldNum(SalesLine, DevReceiptDateRequested)) ||
              this.AxSalesTable().isFieldModified(fieldNum(SalesTable, DevReceiptDateRequested));
  }

• In der Klasse AxSalesline eine weitere Methode wie folgt erstellen

  public DevSalesReceiptDateRequested DevReceiptDateRequested(DevSalesReceiptDateRequested _DevReceiptDateRequested = dateNull())
  {
     if (!prmisdefault(_DevReceiptDateRequested))
     {
         this.setField(fieldNum(SalesLine, DevReceiptDateRequested), _DevReceiptDateRequested);
     }
   
     return SalesLine.DevReceiptDateRequested;
  }

• In der Klasse AxSalesline eine dritte neue Methode wie folgt erstellen

  protected void setDevReceiptDateRequested()
  {
     if (this.isMethodExecuted(funcName(), fieldNum(SalesLine, DevReceiptDateRequested)))
     {
         return;
     }
     if (this.isDevReceiptDateRequestedSet())
     {
         this.DevReceiptDateRequested(this.AxSalesTable().DevReceiptDateRequested());
     }
  }

• In der Klasse AxSalesLine muss nun die Methode setTableFields um den Aufruf der zuvor angelegten Methode setDevReceiptDateRequested erweitert werden
• In der Klasse AxSalesTable eine neue Methode wie folgt anlegen

  protected void setDevReceiptDateRequested()
  {
      ;
      if (this.isMethodExecuted(funcName(), fieldNum(SalesTable, DevReceiptDateRequested)))
      {
          return;
      }
  }

• In der Klasse AxSalesTable eine weitere Methode wie folgt anlegen

  public DevSalesReceiptDateRequested DevReceiptDateRequested(DevSalesReceiptDateRequested _DevReceiptDateRequested = dateNull())
  {
      ;
      if (!prmisdefault(_DevReceiptDateRequested))
      {
          this.setField(fieldNum(SalesTable, DevReceiptDateRequested), _DevReceiptDateRequested);
      }
  
      return salesTable.DevReceiptDateRequested;
  }

• In der Klasse AxSalesTable muss nun die Methode setTableFields um den Aufruf der zuvor angelegten Methode setDevReceiptDateRequested erweitert werden
• Nun muß noch folgender Code einmalig ausgeführt werden (z.B. per Job) um das neue Feld in die Aktualisierungslogik einzubinden

  SalesTable2LineParameters salesTable2LineParameters;
  ;
  ttsbegin;
  salesTable2LineParameters.clear();
  salesTable2LineParameters.initValue();
  salesTable2LineParameters.fieldId           = fieldNum(SalesTable, DevReceiptDateRequested);
  salesTable2LineParameters.table2LineUpdate  = Table2LineUpdate::Prompt;
  salesTable2LineParameters.insert();
  ttscommit;

Übrigens, die gleiche Logik gibt es natürlich auch einkaufsseitig. Die obige Abfolge und die Codebeispiele wurden unter AX3 entwickelt.

Update vom 28.07.2010: In Dynamics AX 2009 funktioniert die beschriebene Lösung genauso. Lediglich beim auszuführenden Job hat sich der Datentyp des Feldes table2LineUpdate geändert.